net-misc/obligator: allow use of libsqlite3

1 files changed, 38 insertions, 0 deletions

diff --git a/net-misc/obligator/obligator-0.3.0_p20240910-r1.ebuild b/net-misc/obligator/obligator-0.3.0_p20240910-r1.ebuild
new file mode 100644
index 0000000..9b97b1f
--- /dev/null
+++ b/net-misc/obligator/obligator-0.3.0_p20240910-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit go-module
+
+DESCRIPTION="Simple and opinionated OpenID Connect server designed for self-hosters"
+HOMEPAGE="https://github.com/lastlogin-net/obligator"
+BDEPEND=">=dev-lang/go-1.20"
+COMMIT="54bc6d226904adbbda6a2666a4b635a65e79c01f"
+SRC_URI="https://github.com/lastlogin-net/obligator/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+SRC_URI+=" https://share.terinstock.com/${P}-vendor.tar.xz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="MIT"
+LICENSE+=" BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+sqlite"
+
+RDEPEND="
+	sqlite? ( dev-db/sqlite:3 )
+"
+
+src_compile() {
+	if use sqlite; then
+		GOFLAGS+=" -tags=libsqlite3"
+	fi
+	ego build ./cmd/obligator/
+}
+
+src_test() {
+	ego test ./...
+}
+
+src_install() {
+	dobin obligator
+}