*/*: update Plover and dependencies

Signed-off-by: Terin Stock <terinjokes@gmail.com>

1 files changed, 44 insertions, 0 deletions

diff --git a/app-text/plover/plover-5.3.0.ebuild b/app-text/plover/plover-5.3.0.ebuild
new file mode 100644
index 0000000..19858a2
--- /dev/null
+++ b/app-text/plover/plover-5.3.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{13..14} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 desktop pypi
+
+DESCRIPTION="Free and open source real-time stenography engine."
+HOMEPAGE="https://www.openstenoproject.org/plover/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/appdirs[${PYTHON_USEDEP}]
+	dev-python/hidapi[${PYTHON_USEDEP}]
+	dev-python/plover-stroke[${PYTHON_USEDEP}]
+	dev-python/pyserial[${PYTHON_USEDEP}]
+	dev-python/pyside:6[gui,widgets,tools,${PYTHON_USEDEP}]
+	dev-python/python-xlib[${PYTHON_USEDEP}]
+	dev-python/readme-renderer[${PYTHON_USEDEP}]
+	dev-python/requests-cache[${PYTHON_USEDEP}]
+	dev-python/requests-futures[${PYTHON_USEDEP}]
+	dev-python/rtf-tokenize[${PYTHON_USEDEP}]
+	dev-python/wcwidth[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	echo "StartupWMClass=org.openstenoproject.python3" >> linux/${PN}.desktop
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	domenu linux/${PN}.desktop
+	doicon plover/assets/${PN}.png
+	newicon plover/assets/${PN}-icon.svg ${PN}.svg
+}