app-misc/rmqtt: add 0.24.0, drop 0.17.1HEADtrunk

1 files changed, 47 insertions, 0 deletions

diff --git a/app-misc/rmqtt/rmqtt-0.24.0.ebuild b/app-misc/rmqtt/rmqtt-0.24.0.ebuild
new file mode 100644
index 0000000..89d9549
--- /dev/null
+++ b/app-misc/rmqtt/rmqtt-0.24.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES=" "
+RUST_MIN_VER="1.94.0"
+inherit cargo
+
+DESCRIPTION="A scalable distributed MQTT broker"
+HOMEPAGE="https://github.com/rmqtt/rmqtt"
+SRC_URI="https://github.com/rmqtt/rmqtt/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+SRC_URI+=" https://share.terinstock.com/${P}-vendor.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+BDEPEND="virtual/pkgconfig"
+RDEPEND="
+	dev-libs/openssl:=
+	app-arch/zstd:=
+	virtual/zlib:=
+"
+DEPEND="${RDEPEND}"
+
+src_unpack() {
+	cargo_src_unpack
+	ln -s "${WORKDIR}/vendor/"* "${CARGO_HOME}/gentoo/" || die
+}
+
+src_configure() {
+	cargo_gen_config
+	cargo_src_configure --locked --no-default-features --bin rmqttd
+}
+
+src_prepare() {
+	default
+
+	export PKG_CONFIG_ALLOW_CROSS=1
+	export OPENSSL_NO_VENDOR=1
+	export ZSTD_SYS_USE_PKG_CONFIG=1
+}
+
+src_install() {
+	dobin "$(cargo_target_dir)/rmqttd"
+}