# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

RUST_MIN_VER="1.82.0"
CRATES=" "
inherit cargo shell-completion

DESCRIPTION="A better xdg-utils (with regex)"
HOMEPAGE="https://github.com/Anomalocaridid/handlr-regex"
SRC_URI="https://github.com/Anomalocaridid/handlr-regex/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SRC_URI+=" https://share.terinstock.com/${P}-vendor.tar.xz "

LICENSE="MIT"
LICENSE+=" Apache-2.0 MPL-2.0 BSD Unicode-3.0 "
SLOT="0"
KEYWORDS="~amd64"

BDEPEND="sys-devel/gettext"
RDEPEND="${DEPEND}"

src_unpack() {
	cargo_src_unpack
	ln -s "${WORKDIR}/vendor/"* "${CARGO_HOME}/gentoo/" || die
}

src_prepare() {
	default

	export GETTEXT_SYSTEM=1
}

src_configure() {
	cargo_gen_config
	cargo_src_configure --no-default-features --bin handlr
}

src_install() {
	cargo_src_install

	newbashcomp - handlr < <(COMPLETE="bash" "$(cargo_target_dir)/handlr")
	newfishcomp - handlr.fish < <(COMPLETE="fish" "$(cargo_target_dir)/handlr")
	newzshcomp - _handlr < <(COMPLETE="zsh" "$(cargo_target_dir)/handlr")
}