# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

RUST_MIN_VER="1.86.0"
CRATES=" "
inherit cargo

DESCRIPTION="Branchless workflow for Git"
HOMEPAGE="https://github.com/arxanas/git-branchless"
SRC_URI="https://github.com/arxanas/git-branchless/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SRC_URI+=" https://share.terinstock.com/${P}-vendor.tar.xz "

LICENSE="|| ( MIT Apache-2.0 )"
LICENSE+=" MIT Apache-2.0 Unicode-DFS-2016 0BSD Apache-2.0-with-LLVM-exceptions"
LICENSE+=" BSD-2 BSD ISC Unlicense MPL-2.0 CC0-1.0 Boost-1.0"
SLOT="0"
KEYWORDS="~amd64"

BDEPEND="virtual/pkgconfig"
DEPEND="
	dev-libs/libgit2
	dev-db/sqlite:3
"
RDEPEND="${DEPEND}"

src_unpack() {
	cargo_src_unpack
	ln -s "${WORKDIR}/vendor/"* "${CARGO_HOME}/gentoo/" || die
}

src_prepare() {
	default

	export LIBGIT2_NO_VENDOR=1
	export LIBSQLITE3_SYS_USE_PKG_CONFIG=1
	export PKG_CONFIG_ALLOW_CROSS=1
}

src_configure() {
	cargo_gen_config
	cargo_src_configure --no-default-features --bin git-branchless
}

src_install() {
	cargo_src_install --path ./git-branchless
}