1 files changed, 38 insertions, 0 deletions
diff --git a/net-misc/obligator/obligator-0.3.0_p20241212.ebuild b/net-misc/obligator/obligator-0.3.0_p20241212.ebuild
new file mode 100644
index 0000000..2c3f1c0
--- /dev/null
+++ b/net-misc/obligator/obligator-0.3.0_p20241212.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit go-module
+
+DESCRIPTION="Simple and opinionated OpenID Connect server designed for self-hosters"
+HOMEPAGE="https://github.com/lastlogin-net/obligator"
+BDEPEND=">=dev-lang/go-1.20"
+COMMIT="dc0909dd6c1b37f617245d3377bca1f3ecb76b4a"
+SRC_URI="https://github.com/lastlogin-net/obligator/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+SRC_URI+=" https://share.terinstock.com/${P}-vendor.tar.xz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="MIT"
+LICENSE+=" BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+sqlite"
+
+RDEPEND="
+	sqlite? ( dev-db/sqlite:3 )
+"
+
+src_compile() {
+	if use sqlite; then
+		GOFLAGS+=" -tags=libsqlite3"
+	fi
+	ego build ./cmd/obligator/
+}
+
+src_test() {
+	ego test ./...
+}
+
+src_install() {
+	dobin obligator
+}