1 files changed, 62 insertions, 0 deletions
diff --git a/dev-util/mise/mise-2026.10.19.ebuild b/dev-util/mise/mise-2026.10.19.ebuild
new file mode 100644
index 0000000..7d9a1b8
--- /dev/null
+++ b/dev-util/mise/mise-2026.10.19.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES=" "
+RUST_MIN_VER="1.95"
+inherit cargo
+
+DESCRIPTION="The front-end to your dev env"
+HOMEPAGE="https://mise.jdx.dev"
+SRC_URI="https://github.com/jdx/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+SRC_URI+=" https://share.terinstock.com/${P}-vendor.tar.xz "
+
+LICENSE="MIT"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 BSD-2 BSD CDLA-Permissive-2.0 ISC MIT MPL-2.0 openssl
+	Unicode-3.0 ZLIB BZIP2
+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="virtual/pkgconfig"
+RDEPEND="
+	dev-libs/openssl:=
+	app-arch/zstd:=
+	dev-lang/lua:5.1
+"
+DEPEND="${RDEPEND}"
+
+src_unpack() {
+	cargo_src_unpack
+	ln -s "${WORKDIR}/vendor/"* "${CARGO_HOME}/gentoo/" || die
+}
+
+src_configure() {
+	cargo_gen_config
+	cargo_src_configure --locked --no-default-features --features native-tls --bin mise
+}
+
+src_prepare() {
+	default
+
+	export PKG_CONFIG_ALLOW_CROSS=1
+	export OPENSSL_NO_VENDOR=1
+	export ZSTD_SYS_USE_PKG_CONFIG=1
+}
+
+src_install() {
+	dobin "$(cargo_target_dir)/${PN}"
+
+	doman man/man1/mise.1
+
+	# Disable self-update functionality
+	insinto /usr/lib/mise
+	doins "${FILESDIR}"/mise-self-update-instructions.toml
+
+	# Enable paranoid mode system-wide
+	insinto /etc/mise
+	doins "${FILESDIR}"/config.toml
+}